activecell-トラ技２００２年６月号補足

月刊誌

トランジスタ技術（CQ出版社）補足

２００２年６月号
　59999/500000カウントの新型DMMを使ってデータを簡単にロギングする
　EasyComm for Excel のPC5000への対応

●PC-5000,510,520M用通信アダプタRS-KB2のリセット特性tsの調査

tsは，定常状態におけるRTSリセットパルスを受けた後，次のコマンドを正常に受信できるようになるまでのセットアップ時間です．
インターフェース回路のイニシャライズ時間と解釈できます．

●測定手順

①RTS,DTR出力はFalse(マイナスレベル)で1.5秒間待ちます．この間にインターフェース回路の電源は放電されて内部回路はリセットされます．

②RTSをTrue(プラスレベル)にすることによって電源を加えます．そして1.5秒，回路が安定するのを待ちます．

③RTSを1mS間FalseにしてTrueに戻します．インターフェース回路をリセットします．

④一定時間待ちます．この時間がtsになります．

⑤データ送信要求コマンドを送ります．

⑦測定データが受信されれば，tsが臨界点以上で受信されなければ臨界点未満であること意味します．

⑧結果によってtsの値を調整して①に戻ります．境界点が明らかになったら終了します．

●プログラムリスト

Const PortNumber As Long = 1    ' 接続するポート番号
'Tsの調査
Sub MeasTs()
    'TsとはRTSをHighに戻してからデータ送信要求コマンドを受け付けるまでのセットアップタイム
    Dim CMD(7) As Byte      ' データ送信要求コマンド
    Dim Dummy As String     ' 読み出し用文字列変数
    Dim NOISE(0) As Byte    ' ノイズバイト
    Dim t As Long           ' パルス時間
    Dim tDelta As Long      ' 変化値
    Dim StartTime As Date   ' 開始時間
    Dim LoopFlag As Boolean ' 繰り返しフラグ

' コマンドバイトの設定
    CMD(0) = &H10
    CMD(1) = &H2
    CMD(2) = &H0
    CMD(3) = &H0
    CMD(4) = &H0
    CMD(5) = &H0
    CMD(6) = &H10
    CMD(7) = &H3

' ノイズの設定
    NOISE(0) = &HF0

' 初期設定
    Range("A2") = "RUN"
    Range("A1") = "初期リセット"    ' メッセージ
    ec.COMn = PortNumber
    ec.Setting = "9600,n,8,1"
    ec.HandShaking = ec.HANDSHAKEs.No
    ec.RTSCTS = True
    ec.DTRDSR = False

' 計測ループ
    LoopFlag = True
    t = 2000                        ' 計測初期値
    tDelta = 100                    ' 変化量初期値
    
    Do While LoopFlag
        If Range("A2") <> "RUN" Then LoopFlag = False

' リセット
        ec.RTSCTS = False           ' RTS=False
        ec.WAITmS = 1500            ' 1.5秒待つ
        ec.RTSCTS = True            ' リセット解除
        ec.WAITmS = 1500            ' 1.5秒待つ
        Dummy = ec.Ascii            ' 受信バッファを空にする

' リセットパルス
        ec.RTSCTS = False           ' RTS=False
        ec.WAITmS = 1               ' 1mSのリセットパルス
        ec.RTSCTS = True            ' RTS=True

' 遅れ
        Range("A1") = "遅れ時間" & t & "mS"
        ec.WAITmS = t
    
        ' コマンド送信
        ec.Binary = CMD             ' データ送信要求コマンドを送る
        StartTime = Now             ' 送信時間を記録
    
        ' データ受信開始待ち
        Do
            If Range("A2") <> "RUN" Then LoopFlag = False
            If Now > StartTime + TimeSerial(0, 0, 2) Then
                ' 2秒を経過したらエラー確定
                Range("A1") = Range("A1") & "反応しません"
                t = t + tDelta              ' tをもどす
                tDelta = Int(tDelta / 10)   ' 変化量を一桁下げる
                If tDelta = 0 Then
                    ' 決定
                    Range("A1") = t & "mS が最小値でした"
                    LoopFlag = False        ' 完了
                    Exit Do
                End If
                t = t - tDelta              ' tを更新
                Exit Do
            End If
            If ec.InBuffer > 0 Then
                ' 受信開始
                Range("A1") = Range("A1") & "データが送られてきました"
                If t <= 0 Then
                    Range("A1") = Range("A1") & "計測時間がゼロ以下なので計測不能です"
                    LoopFlag = False        ' 完了
                    Exit Do
                End If
                t = t - tDelta              ' tの更新
                Exit Do
            End If
        Loop
    Loop
    Range("A2") = ""        ' A2セルの消去
    ec.COMn = 0             ' ポートを閉じる

End Sub

●計測中のワークシート

●計測が完了したワークシート

●PC-5000,510,520M用通信アダプタRS-KB2のリセット特性trの調査

trは，定常状態におけるRTSリセットパルス幅です．RTSを僅かな時間False(マイナスレベル)にすることによって，インターフェース回路をリセットできます．
RTSはインターフェース回路内部でプラス電源として利用されているだけでなく，リセット入力としても併用されていることを意味します．
インターフェース回路にはタイムアウト処理が無いので，コマンドの強制同期を行なうために使用します．

●測定手順

①RTS,DTR出力はFalse(マイナスレベル)で1.5秒間待ちます．この間にインターフェース回路の電源は放電されて内部回路はリセットされます．

②RTSをTrue(プラスレベル)にすることによって電源を加えます．そして1.5秒，回路が安定するのを待ちます．

③1バイトの無効データを送って0.1秒程度待ちます．

④RTSをFalseに下げて，一定時間後にTrueに戻します．この時間がtrになります．

⑤データ送信要求コマンドを送ります．

⑦測定データが受信されれば，リセットされ，データが送られてこなければリセットされなかったことを意味します．

⑧結果によってtrの値を調整して①に戻ります．境界点が明らかになったら終了します．

●プログラムリスト

Const PortNumber As Long = 1    ' 接続するポート番号
'Trの調査
Sub MeasTr()
    'TrとはRTSをLowにしてHighに戻すことによってインターフェースをリセットする時間
    Dim CMD(7) As Byte      ' データ送信要求コマンド
    Dim Dummy As String     ' 読み出し用文字列変数
    Dim NOISE(0) As Byte    ' ノイズバイト
    Dim t As Long           ' パルス時間
    Dim tDelta As Long      ' 変化値
    Dim StartTime As Date   ' 開始時間
    Dim LoopFlag As Boolean ' 繰り返しフラグ

' コマンドバイトの設定
    CMD(0) = &H10
    CMD(1) = &H2
    CMD(2) = &H0
    CMD(3) = &H0
    CMD(4) = &H0
    CMD(5) = &H0
    CMD(6) = &H10
    CMD(7) = &H3

' ノイズの設定
    NOISE(0) = &HF0

' 初期設定
    Range("A2") = "RUN"
    Range("A1") = "初期リセット"    ' メッセージ
    ec.COMn = PortNumber
    ec.Setting = "9600,n,8,1"
    ec.HandShaking = ec.HANDSHAKEs.No
    ec.DTRDSR = False

' 計測ループ
    LoopFlag = True
    t = 100                         ' 計測初期値
    tDelta = 10                     ' 変化量初期値

Do While LoopFlag
        If Range("A2") <> "RUN" Then LoopFlag = False

' 電源リセット
        ec.RTSCTS = False
        ec.WAITmS = 1500            ' 1.5秒待つ
        ec.RTSCTS = True            ' リセット解除
        ec.WAITmS = 1500            ' 1.5秒待つ
        Dummy = ec.Ascii            ' 受信バッファを空にする

' ノイズ送信
        ec.Binary = NOISE()
        ec.WAITmS = 100             ' 0.1秒待つ

' リセット
        Range("A1") = "遅れ時間" & t & "mS"
        ec.RTSCTS = False           ' RTS=False
        ec.WAITmS = t               ' 遅れ
        ec.RTSCTS = True            ' リセット解除

' 遅れ
        ec.WAITmS = 2000            ' 2秒の遅れ

' コマンド送信
        ec.Binary = CMD             ' データ送信要求コマンドを送る
        StartTime = Now             ' 送信時間を記録

' データ受信開始待ち
        Do
            If Range("A2") <> "RUN" Then LoopFlag = False
            If Now > StartTime + TimeSerial(0, 0, 2) Then
                ' 2秒を経過したらエラー確定
                Range("A1") = Range("A1") & "反応しません"
                t = t + tDelta              ' tをもどす
                tDelta = Int(tDelta / 10)   ' 変化量を一桁下げる
                If tDelta = 0 Then
                    ' 決定
                    Range("A1") = t & "mS が最小値でした"
                    LoopFlag = False        ' 完了
                    Exit Do
                End If
                t = t - tDelta              ' tを更新
                Exit Do
            End If
            If ec.InBuffer > 0 Then
                ' 受信開始
                Range("A1") = Range("A1") & "データが送られてきました"
                If t <= 0 Then
                    Range("A1") = Range("A1") & "計測時間がゼロ以下なので計測不能です"
                    LoopFlag = False        ' 完了
                    Exit Do
                End If
                t = t - tDelta              ' tの更新
                Exit Do
            End If
        Loop
    Loop
    Range("A2") = ""        ' A2セルの消去
    ec.COMn = 0             ' ポートを閉じる

End Sub

●計測中のワークシート

●計測が完了したワークシート

●PC-5000,510,520M用通信アダプタRS-KB2のリセット特性tpの調査

tpはRTSをOnにしてからデータの送受信やリセット等が有効になるまでのプリチャージ時間です．
ポートを開き，設定を行ってからインターフェース回路の電源や回路が安定するまでにの時間と解釈できます．
この時間内にデータ送信要求コマンドを送っても，インターフェースケーブルは何の反応もしないので，その特性を利用して測定します．

●測定手順

①RTS,DTR出力はFalse(マイナスレベル)で2秒間待ちます．この間にインターフェース回路の電源は放電されます．

②RTSをTrue(プラスレベル)にすることによってインターフェースケーブルに電源を加えます．

③一定時間待ちます．この時間がtpの測定値になります．

④1バイトの無効データを送ります．無効データが受信されれば回路が動作したことになります．

⑤2秒間待ちます．この間に十分に電源が立ち上がったものとします(tp≪2000mS)．

⑥データ送信要求コマンドを送ります．

⑦測定データが受信されれば，④のノイズバイトが無視されたことを意味します．また測定データが送られてこないときにはノイズバイトが取り込まれたことを意味します．

⑧結果によってtpの値を調整して①に戻ります．境界点が明らかになったら終了します．

●プログラムリスト

Const PortNumber As Long = 1    ' 接続するポート番号
'Tpの調査
Sub MeasTp()
    'Tpとはインターフェース回路の電源投入から，回路が動作するまでの時間をいいます．
    '測定は電源投入後にノイズデータを送り，それが受け付けられない時間を計測します．
    Dim CMD(7) As Byte      ' データ送信要求コマンド
    Dim Dummy As String     ' 読み出し用文字列変数
    Dim NOISE(0) As Byte    ' ノイズバイト
    Dim t As Long           ' パルス時間
    Dim tDelta As Long      ' 変化値
    Dim StartTime As Date   ' 開始時間
    Dim LoopFlag As Boolean ' 繰り返しフラグ

' コマンドバイトの設定
    CMD(0) = &H10
    CMD(1) = &H2
    CMD(2) = &H0
    CMD(3) = &H0
    CMD(4) = &H0
    CMD(5) = &H0
    CMD(6) = &H10
    CMD(7) = &H3

' ノイズの設定
    NOISE(0) = &HF0

' 計測ループ
    LoopFlag = True
    t = 2000                        ' 計測初期値
    tDelta = 100                    ' 変化量初期値

Do While LoopFlag
        If Range("A2") <> "RUN" Then LoopFlag = False

' 電源Off
        ec.RTSCTS = False
        ec.WAITmS = 2000            ' 2秒待つ
        
        ' 電源On
        Range("A1") = "遅れ時間" & t & "mS"
        ec.RTSCTS = True
        
        ' 遅れ
        ec.WAITmS = t

' ノイズ送信
        ec.Binary = NOISE()
        ec.WAITmS = 2000            ' 2秒待つ

' コマンド送信
        ec.Binary = CMD             ' データ送信要求コマンドを送る
        StartTime = Now             ' 送信時間を記録

' データ受信開始待ち
        Do
            If Range("A2") <> "RUN" Then LoopFlag = False
            If Now > StartTime + TimeSerial(0, 0, 2) Then
                ' 2秒を経過したらノイズは受け入れられた
                Range("A1") = Range("A1") & "ノイズは受け入れられました"
                If t <= 0 Then
                    Range("A1") = Range("A1") & "計測時間がゼロ以下なので計測不能です"
                    LoopFlag = False        ' 完了
                    Exit Do
                End If
                t = t - tDelta              ' tの更新
                Exit Do
            End If
            If ec.InBuffer > 0 Then
                ' 受信開始
                Range("A1") = Range("A1") & "ノイズは無視されました"
                t = t + tDelta              ' tをもどす
                tDelta = Int(tDelta / 10)   ' 変化量を一桁下げる
                If tDelta = 0 Then
                    ' 決定
                    Range("A1") = t & "mS が最小値でした"
                    LoopFlag = False        ' 完了
                    Exit Do
                End If
                t = t - tDelta              ' tの更新
                Exit Do
            End If
        Loop
    Loop
    Range("A2") = ""        ' A2セルの消去
    ec.COMn = 0             ' ポートを閉じる

End Sub

●計測中のワークシート

●計測が完了したワークシート